1: %%% eturnal STUN/TURN server.
2: %%%
3: %%% Copyright (c) 2020-2023 Holger Weiss <holger@zedat.fu-berlin.de>.
4: %%% Copyright (c) 2020-2023 ProcessOne, SARL.
5: %%% All rights reserved.
6: %%%
7: %%% Licensed under the Apache License, Version 2.0 (the "License");
8: %%% you may not use this file except in compliance with the License.
9: %%% You may obtain a copy of the License at
10: %%%
11: %%% http://www.apache.org/licenses/LICENSE-2.0
12: %%%
13: %%% Unless required by applicable law or agreed to in writing, software
14: %%% distributed under the License is distributed on an "AS IS" BASIS,
15: %%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
16: %%% See the License for the specific language governing permissions and
17: %%% limitations under the License.
18:
19: -module(eturnal_SUITE).
20: -compile(export_all).
21: -include_lib("common_test/include/ct.hrl").
22:
23: -type info() :: ct_suite:ct_info().
24: -type config() :: ct_suite:ct_config().
25: -type test_def() :: ct_suite:ct_test_def().
26: -type test_name() :: ct_suite:ct_testname().
27: -type group_def() :: ct_suite:ct_group_def().
28: -type group_name() :: ct_suite:ct_groupname().
29:
30: %% API.
31:
32: -spec suite() -> [info()].
33: suite() ->
34: [{require, {server, [address, udp_port, tcp_port, tls_port, auto_port]}},
35: {timetrap, {seconds, 120}}].
36:
37: -spec init_per_suite(config()) -> config().
38: init_per_suite(Config) ->
39: Server = ct:get_config(server),
40: Address = proplists:get_value(address, Server),
41: UdpPort = proplists:get_value(udp_port, Server),
42: TcpPort = proplists:get_value(tcp_port, Server),
43: TlsPort = proplists:get_value(tls_port, Server),
44: AutoPort = proplists:get_value(auto_port, Server),
45: [{address, Address},
46: {udp_port, UdpPort},
47: {tcp_port, TcpPort},
48: {tls_port, TlsPort},
49: {auto_port, AutoPort} | Config].
50:
51: -spec end_per_suite(config()) -> ok.
52: end_per_suite(_Config) ->
53: ok.
54:
55: -spec init_per_group(group_name(), config()) -> config().
56: init_per_group(_GroupName, Config) ->
57: Config.
58:
59: -spec end_per_group(group_name(), config()) -> ok.
60: end_per_group(_GroupName, _Config) ->
61: ok.
62:
63: -spec init_per_testcase(test_name(), config()) -> config().
64: -ifdef(old_inet_backend).
65: init_per_testcase(start_eturnal, Config) ->
66: set_eturnal_env("eturnal-old-otp.yml", Config);
67: init_per_testcase(stun_tcp_auto, _Config) ->
68: {skip, otp_version_unsupported};
69: init_per_testcase(stun_tls_auto, _Config) ->
70: {skip, otp_version_unsupported};
71: init_per_testcase(_TestCase, Config) ->
72: Config.
73: -else.
74: init_per_testcase(start_eturnal, Config) ->
75: set_eturnal_env("eturnal-new-otp.yml", Config);
76: init_per_testcase(_TestCase, Config) ->
77: Config.
78: -endif.
79:
80: -spec end_per_testcase(test_name(), config()) -> ok.
81: end_per_testcase(_TestCase, _Config) ->
82: ok.
83:
84: -spec groups() -> [group_def()].
85: groups() ->
86: [].
87:
88: -spec all() -> [test_def()] | {skip, term()}.
89: all() ->
90: [start_eturnal,
91: check_status,
92: check_info,
93: check_all_sessions,
94: check_user_sessions,
95: check_disconnect,
96: check_credentials,
97: check_loglevel,
98: check_version,
99: reload,
100: connect_tcp,
101: connect_tls,
102: turn_udp,
103: stun_udp,
104: stun_tcp,
105: stun_tls,
106: stun_tcp_auto,
107: stun_tls_auto,
108: stop_eturnal].
109:
110: -spec start_eturnal(config()) -> any().
111: start_eturnal(_Config) ->
112: ct:pal("Starting up eturnal"),
113: ok = eturnal:start().
114:
115: -spec check_status(config()) -> any().
116: check_status(_Config) ->
117: ct:pal("Checking eturnal status"),
118: {ok, Status} = eturnal_ctl:get_status(),
119: ct:pal("Got eturnal status: ~p", [Status]),
120: true = is_list(Status).
121:
122: -spec check_info(config()) -> any().
123: check_info(_Config) ->
124: ct:pal("Checking eturnal statistics"),
125: {ok, Info} = eturnal_ctl:get_info(),
126: ct:pal("Got eturnal statistics: ~p", [Info]),
127: true = is_list(Info).
128:
129: -spec check_all_sessions(config()) -> any().
130: check_all_sessions(_Config) ->
131: ct:pal("Checking active TURN sessions"),
132: {ok, Sessions} = eturnal_ctl:get_sessions(),
133: ct:pal("Got active TURN sessions: ~p", [Sessions]),
134: true = is_list(Sessions).
135:
136: -spec check_user_sessions(config()) -> any().
137: check_user_sessions(_Config) ->
138: ct:pal("Checking active TURN sessions of user"),
139: {ok, Sessions} = eturnal_ctl:get_sessions("alice"),
140: ct:pal("Got active TURN sessions of user: ~p", [Sessions]),
141: true = is_list(Sessions),
142: ct:pal("Checking active TURN sessions of invalid user"),
143: {error, Reason} = eturnal_ctl:disconnect(alice),
144: ct:pal("Got an error, as expected: ~p", [Reason]).
145:
146: -spec check_disconnect(config()) -> any().
147: check_disconnect(_Config) ->
148: ct:pal("Checking disconnection of TURN user"),
149: {ok, Msg} = eturnal_ctl:disconnect("alice"),
150: ct:pal("Got result for disconnecting TURN user: ~p", [Msg]),
151: true = is_list(Msg),
152: ct:pal("Checking disconnection of invalid TURN user"),
153: {error, Reason} = eturnal_ctl:disconnect(alice),
154: ct:pal("Got an error, as expected: ~p", [Reason]).
155:
156: -spec check_credentials(config()) -> any().
157: check_credentials(_Config) ->
158: Timestamp = "2009-10-30 11:00:00Z",
159: Username = 1256900400,
160: Password = "uEKlpcME7MNMMVRV8rUFPCTIFEs=",
161: ct:pal("Checking credentials valid until ~s", [Timestamp]),
162: {ok, Credentials} = eturnal_ctl:get_credentials(Timestamp, []),
163: {ok, [Username, Password], []} =
164: io_lib:fread("Username: ~u~~nPassword: ~s", Credentials),
165: lists:foreach(
166: fun(Lifetime) ->
167: ct:pal("Checking credentials valid for ~s", [Lifetime]),
168: {ok, Creds} = eturnal_ctl:get_credentials(Lifetime, "alice"),
169: {ok, [Time, Pass], []} =
170: io_lib:fread("Username: ~u:alice~~nPassword: ~s", Creds),
171: {ok, Pass} =
172: eturnal_ctl:get_password(integer_to_list(Time) ++ ":alice"),
173: true = erlang:system_time(second) + 86400 - Time < 5
174: end, ["86400", "86400s", "1440m", "24h", "1d"]),
175: ct:pal("Checking invalid expiry"),
176: lists:foreach(
177: fun(Invalid) ->
178: {error, _Reason1} = eturnal_ctl:get_password(Invalid),
179: {error, _Reason2} = eturnal_ctl:get_credentials(Invalid, [])
180: end, ["Invalid", invalid, [invalid]]),
181: ct:pal("Checking invalid suffix"),
182: {error, _Reason} = eturnal_ctl:get_credentials(Username, invalid),
183: ct:pal("Checking static credentials"),
184: {ok, "l0vesBob"} = eturnal_ctl:get_password("alice").
185:
186: -spec check_loglevel(config()) -> any().
187: check_loglevel(_Config) ->
188: Level = "debug",
189: ct:pal("Setting log level to ~s", [Level]),
190: ok = eturnal_ctl:set_loglevel(list_to_atom(Level)),
191: ct:pal("Checking whether log level is set to ~s", [Level]),
192: {ok, Level} = eturnal_ctl:get_loglevel(),
193: ct:pal("Setting invalid log level"),
194: {error, _Reason} = eturnal_ctl:set_loglevel(invalid),
195: ct:pal("Checking whether log level is still set to ~s", [Level]),
196: {ok, Level} = eturnal_ctl:get_loglevel().
197:
198: -spec check_version(config()) -> any().
199: check_version(_Config) ->
200: ct:pal("Checking eturnal version"),
201: {ok, Version} = eturnal_ctl:get_version(),
202: ct:pal("Got eturnal version: ~p", [Version]),
203: match = re:run(Version, "^[0-9]+\\.[0-9]+\\.[0-9](\\+[0-9]+)?",
204: [{capture, none}]).
205:
206: -spec reload(config()) -> any().
207: reload(_Config) ->
208: CertFile = <<"run/cert.pem">>,
209: ct:pal("Deleting TLS certificate"),
210: ok = file:delete(CertFile),
211: ct:pal("Reloading eturnal"),
212: ok = eturnal_ctl:reload(),
213: ct:pal("Checking whether new TLS certificate was created"),
214: {ok, _} = file:read_file_info(CertFile),
215: ct:pal("Reloading eturnal without changes"),
216: ok = eturnal_ctl:reload().
217:
218: -spec connect_tcp(config()) -> any().
219: connect_tcp(Config) ->
220: Addr = ?config(address, Config),
221: Port = ?config(tcp_port, Config),
222: ct:pal("Connecting to 127.0.0.1:~B (TCP)", [Port]),
223: {ok, Sock} = gen_tcp:connect(Addr, Port, []),
224: ok = gen_tcp:close(Sock).
225:
226: -spec connect_tls(config()) -> any().
227: connect_tls(Config) ->
228: Addr = ?config(address, Config),
229: Port = ?config(tls_port, Config),
230: ct:pal("Connecting to 127.0.0.1:~B (TLS)", [Port]),
231: {ok, TCPSock} = gen_tcp:connect(Addr, Port, []),
232: {ok, TLSSock} = fast_tls:tcp_to_tls(TCPSock, [connect]),
233: ok = fast_tls:close(TLSSock).
234:
235: -spec turn_udp(config()) -> any().
236: turn_udp(Config) ->
237: Addr = ?config(address, Config),
238: Port = ?config(udp_port, Config),
239: Username1 = <<"alice">>,
240: Password1 = <<"l0vesBob">>,
241: Username2 = <<"2145913200">>,
242: Password2 = <<"cLwpKS2/9bWHf+agUImD47PIXNE=">>,
243: Realm = <<"eturnal.net">>,
244: ct:pal("Allocating TURN relay on 127.0.0.1:~B (UDP)", [Port]),
245: ok = stun_test:allocate_udp(Addr, Port, Username1, Realm, Password1),
246: ok = stun_test:allocate_udp(Addr, Port, Username2, Realm, Password2).
247:
248: -spec stun_udp(config()) -> any().
249: stun_udp(Config) ->
250: Addr = ?config(address, Config),
251: Port = ?config(udp_port, Config),
252: ct:pal("Performing STUN query against 127.0.0.1:~B (UDP)", [Port]),
253: Result = stun_test:bind_udp(Addr, Port),
254: ct:pal("Got query result: ~p", [Result]),
255: true = is_tuple(Result),
256: true = element(1, Result) =:= stun.
257:
258: -spec stun_tcp(config()) -> any().
259: stun_tcp(Config) ->
260: Addr = ?config(address, Config),
261: Port = ?config(tcp_port, Config),
262: ct:pal("Performing STUN query against 127.0.0.1:~B (TCP)", [Port]),
263: Result = stun_test:bind_tcp(Addr, Port),
264: ct:pal("Got query result: ~p", [Result]),
265: true = is_tuple(Result),
266: true = element(1, Result) =:= stun.
267:
268: -spec stun_tls(config()) -> any().
269: stun_tls(Config) ->
270: Addr = ?config(address, Config),
271: Port = ?config(tls_port, Config),
272: ct:pal("Performing STUN query against 127.0.0.1:~B (TLS)", [Port]),
273: Result = stun_test:bind_tls(Addr, Port),
274: ct:pal("Got query result: ~p", [Result]),
275: true = is_tuple(Result),
276: true = element(1, Result) =:= stun.
277:
278: -spec stun_tcp_auto(config()) -> any().
279: stun_tcp_auto(Config) ->
280: Addr = ?config(address, Config),
281: Port = ?config(auto_port, Config),
282: ct:pal("Performing STUN query against 127.0.0.1:~B (TCP)", [Port]),
283: Result = stun_test:bind_tcp(Addr, Port),
284: ct:pal("Got query result: ~p", [Result]),
285: true = is_tuple(Result),
286: true = element(1, Result) =:= stun.
287:
288: -spec stun_tls_auto(config()) -> any().
289: stun_tls_auto(Config) ->
290: Addr = ?config(address, Config),
291: Port = ?config(auto_port, Config),
292: ct:pal("Performing STUN query against 127.0.0.1:~B (TLS)", [Port]),
293: Result = stun_test:bind_tls(Addr, Port),
294: ct:pal("Got query result: ~p", [Result]),
295: true = is_tuple(Result),
296: true = element(1, Result) =:= stun.
297:
298: -spec stop_eturnal(config()) -> any().
299: stop_eturnal(_Config) ->
300: ct:pal("Stopping eturnal"),
301: ok = eturnal:stop().
302:
303: %% Internal functions.
304:
305: -spec set_eturnal_env(file:filename_all(), config()) -> config().
306: set_eturnal_env(ConfName, Config) ->
307: DataDir = ?config(data_dir, Config),
308: ConfFile = filename:join(DataDir, ConfName),
309: ok = application:set_env(conf, file, ConfFile),
310: ok = application:set_env(conf, on_fail, stop),
311: ok = application:set_env(eturnal, on_fail, exit),
312: Config.